Solidity 练习：调用父函数

一、题目说明

父合约可以被直接调用，也可以使用关键字 super 调用。

通过使用 super，所有父合约都将被调用。

二、任务列表

• 通过使用 super 调用父合约的 bar 方法来完成 H.bar() 。
• 这个函数将调用 G.bar、F.bar 并且最后调用 E.bar。

三、解答代码

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;

contract E {
    // This event will be used to trace function calls.
    event Log(string message);

    function foo() public virtual {
        emit Log("E.foo");
    }

    function bar() public virtual {
        emit Log("E.bar");
    }
}

contract F is E {
    function foo() public virtual override {
        emit Log("F.foo");
        E.foo();
    }

    function bar() public virtual override {
        emit Log("F.bar");
        super.bar();
    }
}

contract G is E {
    function foo() public virtual override {
        emit Log("G.foo");
        E.foo();
    }

    function bar() public virtual override {
        emit Log("G.bar");
        super.bar();
    }
}

contract H is F, G {
    function foo() public override(F, G) {
        // Calls G.foo() and then E.foo()
        // Inside F and G, E.foo() is called. Solidity is smart enough
        // to not call E.foo() twice. Hence E.foo() is only called by G.foo().
        super.foo();
    }

    function bar() public override(F, G) {
        super.bar();
    }
}

四、参考资料

• Smart Contract Engineer Challenges (opens new window)